Hyperlinking an index

Hi Pamela,

Thank you for your question. Visio doesn’t have a Table of Contents tool like Word has. We have to use a work-around to get the job done. You can do this by using a macro (don’t worry, it’s not that hard).

Below are the steps and the code you can use to create a ‘Table of Contents’:

How to use:
1. Open your Visio document.
2. Press Alt + F11 to launch the Visual Basic Editor (VBE).
3. Select Insert>Module from the Menu Bar in the VBE.
4. Copy the code from below.
5. Paste the code in the right hand window of the VBE.
6. Close the VBE.
7. From the Visio document, select Tools>Macro>Macros (or press Alt + F8).
8. Highlight TableOfContents in the list of macros.
9. Press run.

Test the code:
1. Open the example file.
2. Insert a page in the example file.
3. Run the TableOfContents macro per the instructions above.
4. Notice that the page you added is now listed in the Table of Contents.
5. When you are convinced that it works right, place the code in your document and run it.

Below is the actual code. You should only need to run the macro once (steps above). The macro will create buttons on the first page (initially all on top of each other). You will need to rearrange them manually. To use the buttons, run Visio in Presentation Mode (F5)


Option Explicit

Sub TableOfContents()
' creates a shape for each page in the drawing on the first page of the drawing
' then add a dbl-clk GoTo to each shape so you can double click and go to that Page

Dim PageObj As Visio.Page
Dim TOCEntry As Visio.Shape
Dim CellObj As Visio.Cell
Dim PosY As Double
Dim PageCnt As Double

' ActiveDocument.Pages.Count will give the number of pages, but we are interested
' the number of foreground pages
PageCnt = 0
For Each PageObj In ActiveDocument.Pages
If PageObj.Background = False Then PageCnt = PageCnt + 1
Next

' loop through all the pages
For Each PageObj In ActiveDocument.Pages
If PageObj.Background = False Then ' Only foreground pages

' where to put the entry on the page?
PosY = (PageCnt - PageObj.Index) / 4 + 1

' draw a rectangle for each page to hold the text
Set TOCEntry = ActiveDocument.Pages(1).DrawRectangle(1, PosY, 4, PosY + 0.25)

' write the page name in the rectangle
TOCEntry.Text = PageObj.Name

' add a link to point to the page to you can just go there with a Double Click
Set CellObj = TOCEntry.CellsSRC(visSectionObject, visRowEvent, visEvtCellDblClick) 'Start
CellObj.Formula = "GOTOPAGE(""" + PageObj.Name + """)"

End If
Next

'Clean Up
Set CellObj = Nothing
Set TOCEntry = Nothing
Set PageObj = Nothing
End Sub


When it works and you want to save the drawing, you need to save it as a Visio Macro-Enabled Drawing, otherwise you lose the macro.

It works for me, I hope it will for you!

Kind regards
Marius Barnard
Trainer
Best STL